HUDEffectsMut

Тема в разделе "Общего назначения", создана пользователем KeksZ, 22 авг 2011.

  1. SuSpeCT

    SuSpeCT Соучастник

    Люди добрые дайте ссылку пожалуйста я уже С Ноября вас прошу
     
  2. 3xzet

    3xzet Мододел "Ы"

    Код:
    // Written by Dr.TerV for killingfloor.ru
    class HUDEffectsMut extends Mutator
    Config(HUDEffectsMut);
    var() globalconfig bool bSpectatorOverlay, bNearDeathOverlay, bVomitScreen;
    function PostBeginPlay()
    {
     
    if ( !bSpectatorOverlay )
      class'HUDKillingFloor'.default.SpectatorOverlay = none;
     
    /*if ( !bNearDeathOverlay )
      KFHUD.NearDeathOverlay = none;*/
    
    if ( !bVomitScreen )
      if ( class'DamTypeVomit'.default.HudTime > 0)
       class'DamTypeVomit'.default.HudTime = 0.000000;
    }
    static function FillPlayInfo(PlayInfo PlayInfo)
    {
    Super.FillPlayInfo(PlayInfo);
    
    PlayInfo.AddSetting("HUD Effects","bSpectatorOverlay","Film Grain",1,0, "Check");
    //PlayInfo.AddSetting("HUD Effects","bNearDeathOverlay","Near death screen",1,0, "Check");
    PlayInfo.AddSetting("HUD Effects","bVomitScreen","Bloat vomit",1,0, "Check");
    }
    defaultproperties
    {
    	 bAddToServerPackages=True
    	 GroupName="KF-HUDEffectsMut"
    	 FriendlyName="HUDEffectsMut"
    	 Description="Disable/enable HUD effects(film grain, red screen, etc)"
    }
    
     
    ЛОХМАТЫЙ, Flame и Папка01 нравится это.
  3. SuSpeCT

    SuSpeCT Соучастник

    Спасибо большое :)
     
  4. warpel

    warpel Солдат

    KLEYDOX, ЛОХМАТЫЙ и Папка01 нравится это.
  5. Maksovich

    Maksovich Соучастник

    Нет, так и не работает. Что 2 года назад когда был сервер, что сейчас снова решил его запустить. Под виндой в одиночной игре работает, но на сервере пол линуксом (CentOS6.1) не работает. И в ServerPackages прописывал и напрямую грузил и через MutLoader. На сервере появляется, INI файл создается, настройки видно через веб панель, клиенту файл скачивается, но все ровно не работает.
     
  6. Essence

    Essence Moderator Команда форума

    И не будет работать, толку то, что он на клиент закачивается, если код у него не выполняется.

    Код:
    Код:
    // Written by Dr.TerV for killingfloor.ru
    // Fixed by Essence
    class HUDEffectsMut extends Mutator
        Config(HUDEffectsMut);
    
    var config bool bSpectatorOverlay, bVomitScreen;
    
    // Реплицируем серверные настройки на клиент
    replication
    {
        reliable if(Role==ROLE_Authority)
            bSpectatorOverlay, bVomitScreen;
    }
    
    // Даём время на репликацию переменных
    simulated function PostBeginPlay()
    {
        SetTimer(1.0, False);
    }
    
    // В таймере работаем с настройками
    simulated function Timer()
    {
        if(!bSpectatorOverlay)
            Class'HUDKillingFloor'.Default.SpectatorOverlay=None;
        if(!bVomitScreen)
        {
            if(Class'DamTypeVomit'.Default.HudTime>0.0)
                Class'DamTypeVomit'.Default.HudTime=0.0;
       }
    }
    
    static function FillPlayInfo(PlayInfo PlayInfo)
    {
        Super.FillPlayInfo(PlayInfo);
        PlayInfo.AddSetting("HUD Effects","bSpectatorOverlay","Film Grain",1,0,"Check");
        PlayInfo.AddSetting("HUD Effects","bVomitScreen","Bloat vomit",1,0,"Check");
    }
    
    defaultproperties
    {
        bAlwaysRelevant=True
        RemoteRole=ROLE_SimulatedProxy
        bAddToServerPackages=True
        GroupName="KF-HUDEffectsMut"
        FriendlyName="HUDEffectsMut"
        Description="Disable/enable HUD effects(film grain, red screen, etc)"
    }

    Ссылка
     
    Последнее редактирование: 15 дек 2019
  7. Maksovich

    Maksovich Соучастник

    Все ровно не хочет работать. Если что, то я скомпилиповал код из спойера. По ссылке там старая версия мутатора. Единственное что я изменил так это сразу добавил настройки.

    defaultproperties
    {
    bAlwaysRelevant=True
    RemoteRole=ROLE_SimulatedProxy
    bAddToServerPackages=True
    bSpectatorOverlay=False
    bVomitScreen=True
    GroupName="KF-HUDEffectsMut"
    FriendlyName="HUDEffectsMut"
    Description="Disable/enable HUD effects(film grain, red screen, etc)"
    }
     
    Последнее редактирование: 15 дек 2019
  8. Essence

    Essence Moderator Команда форума

    Тестил на чистом выделенном сервере - всё ок.
    Пусть ещё кто-нить потестит или ищите проблему с вашей стороны.
     
  9. Essence

    Essence Moderator Команда форума

    А, да, мой косяк
    Поправил ссылку
     
  10. Maksovich

    Maksovich Соучастник

    Вобщем не знаю что не так, но ни в какую не хочет. Пробовал и сам компилировать и то что по ссылке ставить. Также отключил все мутаторы оставив только этот. Не хочет работать. Уж не знаю что еще там можно сделать.
     
  11. Essence

    Essence Moderator Команда форума

    Попробуйте увеличить время, спустя которое запустится таймер.
    Возможно, не хватает времени для репликации серверных настроек на клиент.
    Код:
    simulated function PostBeginPlay()
    {
        SetTimer(2.0, False); // Попробуйте 2-5 секунд
    }
     
  12. Maksovich

    Maksovich Соучастник

    Понял в чем дело. Мутатор срабатывает тогда когда была смена карты и игрок был при этом на сервере. Если зайти во время игры на сервер то ничего не произойдет. Я думаю надо применение настроек повесить на событие захода игрока на сервер или что-то типа того?